;==================================
; Script Name: Fast Gold Looting Assistant
; Author: Rancid One
; Version: 1.1
; Client Tested with: 4.0.2a
; EUO version tested with: 1.42.007e
; Shard OSI / FS: FS Abrupt Utopia (RunUO 1.0)
; Public Release: 5/14/2004
; Purpose: Loot gold from corpses. It will only attempt to loot
; from a corpse that you have opened yourself, it does NOT
; auto open corpses (so it doesn't screw you up in the heat
; of battle).
;==================================
;VERSION INFO
;--------------------------------------------------
;1.1:
; -Fixed a problem where the script was trying to loot from any container rather than just corpses.
; This also made it stop looting from treasure chests (wich I liked and might add back in later)
; -Changed the IgnoreMyGold sub to be more efficient. (Thanks Quintok)
;1.0:
; -Initial Release of script.
initevents
;--------------------------------------------------
;SETUP
;--------------------------------------------------
;Set %LootBagX and %LootBagY to the coords of a bag to drop the gold into
; (I use my backpack in the paperdoll)
;Set %BackPackID to the ID of your loot bag.
;--------------------------------------------------
SET %BackPackID LWHVSMD ;Loot Bag
SET %LootBagX 1032
SET %LootBagY 440
;--------------------------------------------------

_init:
GoSub IgnoreMyGold
SET %CorpseID 0
SET %GoldID 0

_start:
GoSub FindCorpse
GoTo _start

SUB IgnoreMyGold
_IgnoreMyGoldLoop:
finditem POF C_ , %BackPackID
IF #FINDKIND <> -1
{
ignoreitem #FINDID
goto _IgnoreMyGoldLoop
}
RETURN

SUB FindCorpse
IF #CONTTYPE = YFM
{
SET %CorpseID #CONTID
GoSub FindGold
}
RETURN

SUB FindGold
findItem POF C_ , %CorpseID
SET %GoldID #FINDID
IF #FINDKIND <> -1
GoSub GrabLoot
IF #FINDKIND = -1
IgnoreItem %CorpseID
RETURN

SUB GrabLoot
Event Drag %GoldID
GoSub DragWait
KEY ENTER
If #CONTNAME = stack_gump
click 100 100
Click %LootBagX %LootBagY p
RETURN

SUB DragWait
for %i 1 5
{
IF #CONTSIZE = 168_74
RETURN
wait 5
}
Goto _start
RETURN