Baþta Postmodern Darbe isimli oyuncumuz olmak üzere tüm poi kasmak isteyen oyuncularýmýza gelsin :P

* Bu script ile birlikte sýfýrdan yüze kadar sýkýntýsýz bir þekilde poisoning skilinizi kasabilirsiniz..

Gerekli Malzemeler

* Skilinizin gerektirdiði poison kegi

* 5-10 adet FishSteak (magery kitabýnda bulunan create food büyüsü ile temin edebilirsiniz.)

* 100 adet bandaj


Scripti baþlatmadan evvel yapýlmasý gerekenler

* Banka önünde kasmanýz menfaatinize olacaktýr..Zira script banka içerisine koyacaðýnýz kegleri de kullanýr. . .

* Razordan bandaj makrosu yapmalýsýnýz... Bandaj basma aralýðýný on saniye yapsanýzda yeterli olacaktýr...

* Keg bittiðinde hangi sayfada olursanýz olun uyarý verecektir... Uyarýlarý takip ediniz...



Not : Scriptin Orjinalinde bulunan hide olma özelliðini sildim...

Kolay gelsin.. Ýyi oyunlar dilerim :)





;==========================================
; Script Name: Uncle Dave's Simple Poisoner
; Author: Uncle Dave
; Version: 1.0
; Client Tested with: 4.0.7b
; EUO version tested with: 1.42.009F
; Shard OSI / FS: OSI
; Revision Date: 1/31/2005
; Public Release: 1/31/2005
; Global Variables Used: None
; Purpose: Trains poisoning using fish
; steaks and kegs. Cures using magery.
;==========================================

display okcancel Be sure to open and position any containers containing$
+poison kegs and fish steaks. Once the script starts,$
+do not move your backpack!$$
+Press OK to start the script, or cancel if you need to$
+arrange your desktop.

if #dispres = cancel
halt

set %fishsteak HND
set %poison AVF
set %keg QMJ

gosub EnsurePaperdoll
gosub EnsureStatusbar
gosub EnsureBackpack

set %stackdropx %x + 131
set %stackdropy %y + 68
set %singledropx %x + 95
set %singledropy %y + 50

_main_loop:
gosub CheckSkill
gosub FindFishSteak
gosub FindKeg
gosub FindPoison
gosub PoisonSteak
gosub CureMyself
goto _main_loop

sub CheckSkill
chooseskill poisoning
if #skill < #skillcap
return
display ok Congratulations, you have reached your skill cap!
halt
return

sub Hide
if H in #charstatus
return
_hide_wait:
if #scnt < %skilltimer
goto _hide_wait
event macro 13 21 ; use skill Hiding
set %skilltimer #scnt + 10
wait 1s
return

sub FindKeg
set %i 1
_findkeg_top:
if %kegid <> N/A
{
gosub GetProperty %kegid
set #sysmsgcol 1153
event sysmessage #property
if keg , #spc , is , #spc , empty in #property
set %kegid N/A
}
if %kegid = N/A
{
finditem %keg %i C
if #findkind = -1
{
display ok No kegs found
halt
}
gosub GetProperty #findid
if green in #property || poison in #property
{
set %kegid #findid
goto _findkeg_top
}
set %i %i + 1
goto _findkeg_top
}
return

sub FindPoison
_findpoison_top:
finditem %poison C
if #findkind = -1
{
gosub UseItem %kegid
goto _findpoison_top
}
set %poisonid #findid
return

sub FindFishSteak
if %fishsteakid <> N/A
gosub MoveItem %fishsteakid 0 %stackdropx %stackdropy
_findfishsteak_top:
finditem %fishsteak C_ , #backpackid
if #findkind = -1
{
finditem %fishsteak C
if #findkind = -1
{
display ok No fish steaks found
halt
}
gosub MoveItem #findid 3 %stackdropx %stackdropy
goto _findfishsteak_top
}
if #findcnt > 1
{
for %i 1 #findcnt
{
finditem %fishsteak %i C_ , #backpackid
gosub MoveItem #findid 0 %stackdropx %stackdropy
}
goto _findfishsteak_top
}
gosub MoveItem #findid 1 %singledropx %singledropy
set %i 1
_findfishsteak_single:
finditem %fishsteak %i C_ , #backpackid
if #findkind = -1
goto _findfishsteak_top
if #findstack > 1
{
set %i %i + 1
goto _findfishsteak_single
}
set %fishsteakid #findid
return

sub PoisonSteak
_poisonsteak_top:
if #scnt < %skilltimer
goto _poisonsteak_top
set %jindex #jindex
event macro 13 30 ; use skill Poisoning
gosub WaitForTarget
if #result = #false
goto _poisonsteak_top
set #ltargetid %poisonid
set #ltargetkind 1
event macro 22 0 ; last target
target 3s
set #ltargetid %fishsteakid
set #ltargetkind 1
event macro 22 0 ; last target
wait 1s
set %skilltimer #scnt + 10
return

sub WaitForTarget
_waitfortarget_top:
if #jindex > %jindex
{
set %jindex %jindex + 1
scanjournal %jindex
if must_wait in #journal
{
wait 1s
return #false
}
}
if #targcurs = 0
goto _waitfortarget_top
return #true

sub CureMyself
gosub EnsureStatusbar
_curemyself_top:
if C in #charstatus
{
event macro 15 10 ; cast spell Cure
target 6s
event macro 23 0 ; target self
wait 3s
goto _curemyself_top
}
return

sub EnsurePaperdoll
_ensurepaperdoll_top:
if #contid <> #charid || #contname <> paperdoll_gump
{
event macro 8 1 ; Open Paperdoll
wait 1s
goto _ensurepaperdoll_top
}
set %x #clileft + #clixres
set %y #clitop + #cliyres
if ( #contposx < %x ) && ( #contposy < %y )
{
set %x %x + 10
contpos %x 15
wait 2
}
set %x #contposx
set %y #contposy
return

sub EnsureStatusBar
_ensurestatusbar_top:
if #contid <> #charid || #contname <> status_gump
{
event macro 8 2 ; Open Status
wait 1s
goto _ensurestatusbar_top
}
set %x #clileft + #clixres
set %y #clitop + #cliyres
if ( #contposx < %x ) && ( #contposy < %y )
{
set %x %x + 10
contpos %x 350
wait 2
}
set %x #contposx
set %y #contposy
return

sub EnsureBackpack
_ensurebackpack_top:
if #contid <> #backpackid
{
event macro 8 7 ; Open Backpack
wait 2s
goto _ensurebackpack_top
}
set %x #clileft + #clixres
set %y #clitop + #cliyres
if ( #contposx < %x ) && ( #contposy < %y )
{
set %x %x - 230
set %y %y + 10
contpos %x %y
wait 2
}
set %x #contposx
set %y #contposy
return

sub GetProperty
_getproperty_retry:
event property %1
if #property = $ || #property = #spc , $ || #property = N/A
goto _getproperty_retry
return

sub UseItem
set #lobjectid %1
event macro 17 0 ; Last Object
wait 2s
return

sub MoveItem
if %2 < 1
set %2
_moveitem_retry:
msg $
set %jindex #jindex
set %timer #systime + 1100
event drag %1
_moveitem_wait:
if #contname = stack_gump
{
set %timer #systime + 1100
msg %2 , $
wait 5
goto _moveitem_wait
}
if #jindex > %jindex
{
set %jindex %jindex + 1
scanjournal %jindex
if must_wait in #journal
{
wait 5
goto _moveitem_retry
}
if too_far in #journal || can_not_pick in #journal
{
wait 15 ; prevent must_wait on next round
return #false
}
}
if #systime < %timer
goto _moveitem_wait
if #lliftedkind = 0
goto _pickupitem_retry
_moveitem_click:
click %3 %4 p
wait 15 ; prevent must_wait on next round and give time for item to drop
if #lliftedkind = 1
goto _moveitem_click
return #true

Eyvallah Emre sayende poi kasacam :)

Bende belki mf yi fense çevirebilirim bi kryss çýkarsa

Baltalamak gibi olmasin, bitmediði halde fish steaks bitti uyarýsý aldým kaç kere. Sonradan baþka bir script buldum. Bu sorunsuz çalýþýyor: http://forum.worldofuo.com/yardimci-programlar/poisoning-kasma-scripti/

Easy uo ile uðraþmak istemeyenler için

Razordan makro ile kasma yöntemi

1-Kege çift týkla
2-0.50 saniye bekle
3-Skill kullan poisoning
4-1 saniye bekle
5-Poi potuna týkla
6-1 saniye bekle
7-Poi sürmek istediðin þeye týkla
8-7 saniye bekle


Kaydý durdurduktan sonra 3.adýma sað týklayýp tipine göre hedefe çevir diyoruz. Çantamýza keg ve 1 2 tane boþ pot alýyoruz. Çalýþtýrýyoruz