;==================================
; Script Name: Wool gather (Sheeps)
; Author: yolcu
; Version: 2.0.0
; Language: Turkish
; Client Tested with: 7.0.57.1
; EUO version tested with: 1.5.1.309
; Shard OSI / FS: FS
; Public Release: 02-12-2017
; Revision : 04-12-2017
; Global Variables Used: N/A
; Purpose: again and again get whool from sheeps and go back to bank
;==================================
; Requirements:
; - min 64.0 Magery Skill
; - min %100 LRC
; - SpellBook with Lightning, Recall and Heal
; - Dagger in BackPack
; - RuneBook with min 2 runes, first Bank , others sheep locations
initevents
menu hideEUO
menu Window Size 300 110
menu Text InfoLabel 20 50 Yükleniyor lütfen bekleyin ...
menu show
set %yun OFF
set %Koyun PF
set %KoyunID N/A
set %DaggerID N/A
set %RuneBook N/A
set %FCRWait N/A
set %runeIndex 2
set %maxRuneIndex 16
set %NextCast #systime
set %BankBox N/A
gosub openPaperdoll
gosub openBackPack
gosub openStatus
gosub SetFCRWait
set #MenuButton N/A
gosub scriptMenu
menuLoop:
gosub #MenuButton
goto menuLoop
sub scriptMenu
{
    menu Clear
    menu Window Title Yün toplayýcý
    menu Window Size 300 110
    menu Button cmdRuneBook 10 10 86 30 &Runebook
    menu Text labelRuneBook 106 17 %RuneBook
    menu Edit editMaxRuneIndex 186 15 30 %maxRuneIndex
    menu Button cmdStart 59 70 86 30 &Baþlat
    menu Button closed 155 70 86 30 &Kapat
    return
}
sub startedMenu
{
    menu clear
    menu Window Size 300 50
    menu Button cmdStop 59 10 86 30  &Durdur
    menu Button closed 155 10 86 30 &Kapat
    return
}
sub OpenPaperdoll
{
    _openPaperdoll:
    event macro 8 1 ; Open Paperdoll
    gosub WaitForGump paperdoll_gump
    if #result
        contPos #cliXRes 0
    else
        goto _openPaperdoll
    return
}
sub openBackPack
{
    _openBackPack:
    event macro 8 7 ; Open BackPack
    gosub WaitForGump container_gump 230_204
    if #result
        contPos #cliXRes 500
    else
        goto _openBackPack
    return
}
sub OpenStatus
{
    _openStatus:
    event macro 8 2 ; Open BackPack
    gosub WaitForGump status_gump
    event macro 10 2 ; minimize status
    gosub WaitForGump status_gump
    if #result
    {
       set #contPosX ( ( #cliXRes / 2 ) - 75 )
       set #contPosY #cliYRes - 123
    }
    else
        goto _openStatus
    return
}
sub cmdRuneBook
{
    set #MenuButton N/A
    set #targCurs 1
    targLoop:
    if #targCurs = 1
        goto targLoop
    set %RuneBook #LTargetID
    finditem %RuneBook C_ , #BackPackID
    if #findtype <> ZBN
        set %RuneBook N/A
    menu set labelRuneBook %RuneBook
    return
}
sub cmdStart
{
    set #MenuButton N/A
    chooseSkill mage
    if #skill < 640
    {
        menu set InfoLabel Yetersiz Magery skill. min: 64.0 !
        return
    }
    finditem %RuneBook C_ , #BackPackID
    if #findtype <> ZBN || #findCnt < 1
    {
        menu set InfoLabel Baþlamak için çantanýzdan Runebook seçiniz !
        return
    }
    menu getNum editMaxRuneIndex 0
    set %maxRuneIndex #menures
    if %maxRuneIndex <= 0 || %maxRuneIndex > 16
    {
        menu set InfoLabel Lütfen kitaptaki rune adedini giriniz !
        return
    }
    finditem VRH_WSF_HNF_BPH_CNF C_ , #BackPackID
    if #FINDCNT < 0
    {
        menu set InfoLabel Çantanýzda dagger bulunamadý !
        return
    }
    set %DaggerID #findID
    gosub startedMenu
    mainLoop:
    gosub koyunBul
    if #MenuButton = N/A
        goto mainLoop
    return
}
sub cmdStop
{
    set #MenuButton N/A
    gosub scriptMenu
    return
}
sub closed
{
    menu hide
    halt
    return
}
sub koyunBul
{
    _koyunBul:
    finditem %Koyun G
    if #findcnt > 0
    {
        set %KoyunID #findID
        set %FDist #findDist
        if #findCnt > 1
        {
            for %i 1 #findCnt
            {
                findItem %Koyun %i G
                if #findDist < %FDist
                {
                    set %FDist #findDist
                    set %KoyunID #findID
                }
            }
        }
        gosub Kirp
    }
    else
    {
        findItem FG G
        while #findCnt > 0
        {
            set %KoyunID #findID
            gosub Oldur
            findItem FG G
        }
        ignoreItem Reset
        gosub GoToNextRune
    }
    return
}
sub GoToNextRune
{
    while %NextCast > #systime
        wait
    gosub UseRunebook %runeIndex
    set %NextCast #systime + %FCRWait
    set %runeIndex %runeIndex + 1
    if %runeIndex > %maxRuneIndex
        set %runeIndex 2
    return
}
sub getCloser
{
    finditem %KoyunID
    while #finddist > 2
    {
        move #findX #findY 1 4
        finditem %KoyunID
    }
    return
}
sub Kirp
{
    tekrarKirp:
    finditem %KoyunID
    if #findCnt > 0
    {
        set #LObjectID %DaggerID
        set #LTargetID %KoyunID
        set #LTargetKind 1
        event Macro 17
        target 9s
        gosub getCloser
        set %jrnl #jIndex
        event Macro 22
        gosub WaitForMessage
        if ! #result
            goto tekrarKirp
        gosub Oldur
    }
    gosub AgirlikKontrol
    gosub healthKontrol
    return
}
sub Oldur
{
    finditem %KoyunID
    if #findCnt > 0
    {
        event property %KoyunID
        if ! ( tame in #property || bonded in #property )
        {
            gosub getCloser
            while %NextCast >= #systime
                wait
            event macro 15 4 ; Magic Arrow
            ;event macro 15 29 ; Lightning
            ;event macro 15 17 ; FireBall
            target 6s
            set #LTargetID %KoyunID
            set #LTargetKind 1
            event macro 22 ; Last Target
            set %NextCast #systime + %FCRWait
        }
        ignoreItem %KoyunID
    }
    return
}
sub AgirlikKontrol
{
    if #WEIGHT >= ( #MAXWEIGHT - 9 )
        gosub bankayaGit
    return
}
sub bankayaGit
{
    _bankRune:
    if #MenuButton <> N/A
        return
    while %NextCast >= #systime
        wait
    gosub UseRunebook 1
    if ! #result
    {
        set %NextCast #systime + %FCRWait
        goto _bankRune
    }
    set %NextCast #systime + %FCRWait
    _banka:
    msg #spc , Bank $
    gosub WaitForGump container_gump 180_240
    if %BankBox = N/A
        set %BankBox #ContID
    finditem %Yun C_ , #BackPackID
    while #FINDCNT > 0
    {
        exevent Drag #FINDID #FINDSTACK
        wait 10
        exevent Dropc %BankBox
        wait 5
        finditem %Yun C_ , #BackPackID
    }
    if #mana < #maxMana
    {
        event sysMessage Mana bekleniyor...
        event macro 13 46
        while #mana < #maxMana
            wait
    }
    set %runeIndex %runeIndex - 1
    if %runeIndex < 2
        set %runeIndex %maxRuneIndex
    _currentRune:
    while %NextCast > #systime
        wait
    gosub UseRunebook %runeIndex
    set %NextCast #systime + %FCRWait
    if ! #result
        goto _currentRune
    set %runeIndex %runeIndex + 1
    if %runeIndex > %maxRuneIndex
        set %runeIndex 2
    return
}
sub HealthKontrol
{
    while #hits < #maxHits && #mana >= 4
    {
        while %NextCast >= #systime
            wait
        event macro 15 3 ; Heal
        target 9s
        event macro 23 ; Target Self
        set %NextCast #systime + %FCRWait
    }
    return
}

sub UseRunebook
{
    while #mana < 11
        wait
    set !runebook %RuneBook
    set !index %1
    set !fails 0
    set !oldPosX 0
    set !oldPosY 0
    set #result #true
    if #contsize = 452_236
    {
        set !_cx #contposx + 20
        set !_cy #contposy + 20
        click !_cx !_cy r f dmc
        wait 5
    }
    for !orb 1 1
    {
        set !jStart #jindex
        set #lobjectid !runebook
        event macro 17 ; LastObject Open RuneBook
        gosub WaitForGump generic_gump 452_236
        if ! #result
            set !orb 0
        if #result
        {
            set !_cy #contposy + 196
            set !_cx #contposx + 105 + ( ( ( !index / 2 ) + ( !index % 2 ) ) * 35 )
            if !index > 8
                set !_cx !_cx + 30
            click !_cx !_cy f dmc
            wait 5
            set !_cx #contposx + 135
            set !_cy #contposy + 144
            if ( !index % 2 ) = 0
                set !_cx !_cx + 160
            set !oldPosX #charposx
            set !oldPosY #charposy
            set !timeout #scnt2
            click !_cx !_cy f dmc
        }
        if !orb = 1
        {
            set !lpc #lpc
            set #lpc 100
            for !success 1 1
            {
                if !oldPosX = #charposx && !oldPosY = #charposy
                    set !success 0
                if #jIndex > !jStart
                {
                    set !jEnd #jIndex
                    for !jrnl !jStart !jEnd
                    {
                        scanjournal !jrnl
                        if disturb in #journal || location_is_blocked in #journal || not_yet_recovered in #journal || tithing_points in #journal || insufficient_mana in #journal || not_marked in #journal
                        {
                            set !success 1
                            set #result #false
                        }
                    }
                    set !jStart !jEnd
                }
            }
            set #lpc !lpc
            if #result && !index <> 1
                wait 20
        }
    }
    return #result
}
sub WaitForMessage
{
    while #true
    {
        if #jindex > %jrnl
        {
            set %jrnl %jrnl + 1
            scanjournal %jrnl
            if is_too_far in #journal || you_place in #journal || not_yet in #journal
            {
                if is_too_far in #journal
                    set #result #false
                else
                    set #result #true
                break
            }
        }
    }
    return #result
}
sub WaitForGump
{
    nameSpace push
    nameSpace Local _wfg
    set !timeout #scnt + 4
    set #result #true
    set !contName %1
    set !contSize N/A
    if %0 = 2
        set !contSize %2
    while #contName <> !contName || ( !contSize <> N/A && #contSize <> !contSize )
    {
        if #scnt > !timeout
        {
            set #result #false
            break
        }
    }
    nameSpace Clear _wfg
    nameSpace pop
    return #result
}
sub SetFCRWait
{
    set %FCR 0
    set %FCRText faster , #spc , cast , #spc , recovery
    finditem IJG_CWL C_ , #CHARID ; Bracelet
    if #findCnt > 0
    {
        event property #findID
        if %FCRText in #property
        {
            str pos #property %FCRText
            set %FCR_ #strres + 21
            str Mid #property %FCR_ 1
            set %FCR %FCR + #strres
        }
    }
    finditem UJG_LWL C_ , #CHARID ; Ring
    if #findCnt > 0
    {
        event property #findID
        if %FCRText in #property
        {
            str pos #property %FCRText
            set %FCR_ #strres + 21
            str Mid #property %FCR_ 1
            set %FCR %FCR + #strres
        }
    }
    if %FCR > 6
        set %FCR 6
    set %FCRWait 1500 - ( %FCR * 250 )
    return
}

sub HealthKontrol
{
    while #hits < #maxHits && #mana >= 11
    {
        while %NextCast >= #systime
            wait
        event macro 15 28
        target 9s
        event macro 23 ; Target Self
        set %NextCast #systime + %FCRWait
    }
    return
}

sub Oldur
{
    finditem %KoyunID
    if #findCnt > 0
    {
        gosub getCloser
        while %NextCast >= #systime
            wait
        ; Kullanmak istediðin büyünün olduðu satýrýn baþýndaki noktalý virgülü kaldýr,
        ; Diðerlerine noktalý virgül koy
        ;event macro 15 4 ; Magic Arrow
        ;event macro 15 29 ; Lightning
        event macro 15 17 ; FireBall
        target 6s
        set #LTargetID %KoyunID
        set #LTargetKind 1
        event macro 22 ; Last Target
        set %NextCast #systime + %FCRWait
        ignoreItem %KoyunID
    }
    return
}