initevents
set %DomatesCorbasi MLI
set %Kurabiye ZNQ
set %HindistanCevizi RWI
set %ExpArttirici %DomatesCorbasi , _ , %Kurabiye , _ , %HindistanCevizi
set %Container generic_gump
set %SuccessMessage fazla_deneyim_puan
set %AlreadyMessage fazla_yememelisin
set %LastSuccess #time
set %NextUse #scnt
set %TimeToAdd 0
set %ExectTimer #false
set %MenuUpdated #false
set %jrnl #jIndex
set #MenuButton N/A
gosub OpenBackPack
menu hideEUO
gosub scriptMenu
mainLoop:
gosub #MenuButton
gosub ExpArttiriciKullan
gosub updateMenu
goto mainLoop
sub scriptMenu
{
    menu Window size 300 100
    menu text InfoLabel 10 10
    menu text TimerLabel 10 30
    menu Button closed 107 60 86 30 &Kapat
    menu Show
    return
}
sub updateMenu
{
    if %ExectTimer && ! %MenuUpdated
    {
        set !time
        str mid %LastSuccess 1 2
        set !time #strres , :
        str mid %LastSuccess 3 2
        set !time !time , #strres , :
        str mid %LastSuccess 5 2
        set !time !time , #strres
        menu set InfoLabel Son kullaným : !time
        set %MenuUpdated #true
    }
    if ! %ExectTimer
    {
        menu set InfoLabel Ýlk baþarýlý kullaným bekleniyor.
    }
    set !timerMins ( %NextUse - #scnt ) / 60
    set !timerSecs ( %NextUse - #scnt ) % 60
    menu set TimerLabel Sonraki Kullanýma !timerMins dakika !timerSecs saniye
    return
}
sub expArttiriciBul
{
    set %ExpArttiriciID N/A
    findItem %ExpArttirici C_ , #BackPackID
    if #findCnt < 1
    {
        gosub BulunamadiMesaj
        return
    }
    findItem %DomatesCorbasi C_ , #BackPackID
    if #findCnt > 0
    {
        set %ExpArttiriciID #findId
        set %TimeToAdd 3600 * 2
        return
    }
    findItem %ExpArttirici  C_ , #BackPackID
    if #findCnt > 0
    {
        set %ExpArttiriciID #findId
        if #findType = %Kurabiye
            set %TimeToAdd 3600 * 2
        if #findType = %HindistanCevizi
            set %TimeToAdd 3600
    }
    return
}
sub ExpArttiriciKullan
{
    if %NextUse < #scnt
    {
        gosub expArttiriciBul
        if %ExpArttiriciID = N/A
        {
            gosub closed
        }
        else
        {
            set %MenuUpdated #false
            set #LObjectID %ExpArttiriciID
            set %jrnl #jIndex
            event macro 17 0
            gosub WaitForGump %Container 595_325
            set %cx_ #contposx + 210
            set %cy_ #contposy + 260
            click %cx_ %cy_ f dmc
            gosub WaitMessage
            if %SuccessMessage in #journal
            {
                set %ExectTimer #true
                set %LastSuccess #time
                set %NextUse #scnt + %TimeToAdd
            }
            if %AlreadyMessage in #journal
            {
                set %NextUse #scnt + ( 60 * 5 )
            }
        }
    }
    return
}
sub WaitMessage
{
    while #true
    {
        if #jIndex > %jrnl
        {
            set %jrnl %jrnl + 1
            scanJournal %jrnl
            if %SuccessMessage in #journal || %AlreadyMessage in #journal
                break
        }
    }
    return
}
sub BulunamadiMesaj
{
    display ok Çantanýzda yenilebilir deneyim puaný arttýrýcý bulunamadý ! $
    + Çantanýza yenilebilir alarak tekrar baþlatmayý deneyiniz.
    return
}
sub Closed
{
    menu hide
    halt
}
sub openBackPack
{
    _openBackPack:
    event macro 8 7 ; Open BackPack
    gosub WaitForGump container_gump 230_204
    if #result
        contPos #cliXRes 500
    else
        goto _openBackPack
    return
}
sub WaitForGump
{
    set !timeOut #scnt + 3
    set !result #true
    if %0 = 1
    {
        while #contname <> %1
        {
            if !timeOut < #systime
            {
                set !result #false
                break
            }
        }
    }
    if %0 = 2
    {
        while #contname <> %1 || #contsize <> %2
        {
            if !timeOut < #systime
            {
                set !result #false
                break
            }
        }
    }
    return !result
}